ເນື້ອໃນ

# ຟັງຊັນສະເປຣດຊີດ

ພາກນີ້ປະກອບດ້ວຍຄຳອະທິບາຍຂອງຟັງຊັນ ສະເປຣດຊີດ ພ້ອມກັບຕົວຢ່າງ.

ເພື່ອເຂົ້າເຖິງຄຳສັ່ງນີ້...

ແຊກ - ຟັງຊັນ - ໝວດໝູ່ ສະເປຣດຊີດ

## ERROR.TYPE

ສົ່ງຄືນຕົວເລກທີ່ແທນປະເພດຂໍ້ຜິດພາດທີ່ລະບຸ ຫຼື ສົ່ງຄືນຄ່າຂໍ້ຜິດພາດ #N/A ຖ້າບໍ່ມີຂໍ້ຜິດພາດ.

## LOOKUP

ຄົ້ນຫາເກນໃນອາເຣທີ່ໄດ້ຈັດລຽງລຳດັບໄວ້ແລ້ວ ແລະ ສົ່ງຄືນຜົນລັດທີ່ກົງກັນ. ສົ່ງຄືນເນື້ອໃນຂອງເຊວຈາກຊ່ວງທີ່ມີແຖວດຽວ ຫຼື ຄໍລຳດຽວ.

## STYLE

ນຳໃຊ້ຮູບແບບ (style) ໃຫ້ກັບຫ້ອງທີ່ມີສູດ.

## ADDRESS

ສົ່ງຄືນທີ່ຢູ່ຫ້ອງ (ການອ້າງອີງ) ເປັນຂໍ້ຄວາມ, ຕາມໝາຍເລກແຖວ ແລະ ຖັນທີ່ລະບຸ. ທ່ານສາມາດກຳນົດໄດ້ວ່າທີ່ຢູ່ນັ້ນຈະຖືກແປເປັນທີ່ຢູ່ແບບສຳບູນ (ຕົວຢ່າງ: $A$1), ທີ່ຢູ່ແບບສຳພັນ (ຕົວຢ່າງ: A1) ຫຼື ແບບປະສົມ (A$1 ຫຼື $A1). ນອກຈາກນີ້ ທ່ານຍັງສາມາດລະບຸຊື່ຂອງແຜ່ນງານໄດ້.

ເພື່ອໃຫ້ໃຊ້ງານຮ່ວມກັນໄດ້ ຟັງຊັນ ADDRESS ແລະ INDIRECT ຮອງຮັບພາຣາມິເຕີເສີມເພື່ອລະບຸວ່າຈະໃຊ້ຮູບແບບການຂຽນທີ່ຢູ່ແບບ R1C1 ແທນຮູບແບບ A1 ປົກກະຕິຫຼືບໍ່.

ໃນ ADDRESS, ພາຣາມິເຕີນີ້ຈະຖືກແຊກເປັນພາຣາມິເຕີທີສີ່, ເຊິ່ງຈະເຮັດໃຫ້ພາຣາມິເຕີຊື່ແຜ່ນງານຍ້າຍໄປຢູ່ຕຳແໜ່ງທີຫ້າ.

ໃນ INDIRECT, ພາຣາມິເຕີນີ້ຈະຖືກເພີ່ມເຂົ້າເປັນພາຣາມິເຕີທີສອງ.

ໃນທັງສອງຟັງຊັນ, ຖ້າປ້ອນອາກິວເມັນເປັນຄ່າ 0, ຈະໃຊ້ຮູບແບບການຂຽນແບບ R1C1. ຖ້າບໍ່ໄດ້ລະບຸ ຫຼື ມີຄ່າອື່ນທີ່ບໍ່ແມ່ນ 0, ຈະໃຊ້ຮູບແບບ A1.

ໃນກໍລະນີທີ່ໃຊ້ຮູບແບບ R1C1, ADDRESS ຈະສົ່ງຄືນຂໍ້ຄວາມທີ່ຢູ່ໂດຍໃຊ້ເຄື່ອງໝາຍອັດສະຈັນ '!' ເປັນຕົວຂັ້ນຊື່ແຜ່ນງານ, ແລະ INDIRECT ກໍຕ້ອງການເຄື່ອງໝາຍອັດສະຈັນເປັນຕົວຂັ້ນຊື່ແຜ່ນງານເຊັ່ນກັນ. ແຕ່ທັງສອງຟັງຊັນຍັງຄົງໃຊ້ເຄື່ອງໝາຍຈຳ້ '.' ເປັນຕົວຂັ້ນຊື່ແຜ່ນງານສຳລັບຮູບແບບ A1.

ເມື່ອເປີດເອກະສານຈາກຮູບແບບ ODF 1.0/1.1, ຟັງຊັນ ADDRESS ທີ່ເຄີຍມີຊື່ແຜ່ນງານເປັນພາຣາມິເຕີທີສີ່ ຈະຍ້າຍຊື່ແຜ່ນງານນັ້ນໄປເປັນພາຣາມິເຕີທີຫ້າ ແລະ ຈະມີພາຣາມິເຕີທີສີ່ໃໝ່ທີ່ມີຄ່າ 1 ຖືກແຊກເຂົ້າມາ.

ເມື່ອບັນທຶກເອກະສານໃນຮູບແບບ ODF 1.0/1.1, ຖ້າຟັງຊັນ ADDRESS ມີພາຣາມິເຕີທີສີ່, ພາຣາມິເຕີນັ້ນຈະຖືກລົບອອກ.

ຢ່າບັນທຶກສະເປຣດຊີດໃນຮູບແບບເກົ່າ ODF 1.0/1.1 ຖ້າພາຣາມິເຕີທີສີ່ໃໝ່ຂອງຟັງຊັນ ADDRESS ຖືກໃຊ້ດ້ວຍຄ່າ 0.

ຟັງຊັນ INDIRECT ຈະຖືກບັນທຶກໂດຍບໍ່ມີການແປງເປັນຮູບແບບ ODF 1.0/1.1. ຖ້າມີພາຣາມິເຕີທີສອງຢູ່, Calc ເວີຊັນເກົ່າຈະສະແດງຂໍ້ຜິດພາດສຳລັບຟັງຊັນນັ້ນ.

#### ໄວຍາກອນ

ADDRESS(ແຖວ; ຖັນ [; Abs [; A1 [; "Sheet"]]])

ແຖວ ໝາຍເຖິງ ໝາຍເລກແຖວສຳລັບການອ້າງອີງຫ້ອງ

ຖັນ ໝາຍເຖິງ ໝາຍເລກຖັນສຳລັບການອ້າງອີງຫ້ອງ (ໃຫ້ໃຊ້ຕົວເລກ, ບໍ່ແມ່ນຕົວອັກສອນ)

Abs ກຳນົດປະເພດຂອງການອ້າງອີງ:

1: ສຳບູນ ($A$1)

2: ແຖວເປັນແບບສຳບູນ; ຖັນເປັນແບບສຳພັນ (A$1)

3: ແຖວເປັນແບບສຳພັນ; ຖັນເປັນແບບສຳບູນ ($A1)

4: ສຳພັນ (A1)

A1 (ເລືອກໄດ້) - ຖ້າຕັ້ງເປັນ 0, ຈະໃຊ້ຮູບແບບການຂຽນແບບ R1C1. ຖ້າບໍ່ມີພາຣາມິເຕີນີ ຫຼື ຕັ້ງເປັນຄ່າອື່ນທີ່ບໍ່ແມ່ນ 0, ຈະໃຊ້ຮູບແບບ A1.

Sheet ໝາຍເຖິງ ຊື່ຂອງແຜ່ນງານ. ຕ້ອງໃສ່ໃນເຄື່ອງໝາຍຄຳເວົ້າ (").

### ຕົວຢ່າງ:

=ADDRESS(1;1;2;;"Sheet2") ສົ່ງຄືນຜົນດັ່ງນີ້: Sheet2.A$1

ຖ້າສູດຂ້າງເທິງນັ້ນຢູ່ໃນຫ້ອງ B2 ຂອງແຜ່ນງານປັດຈຸບັນ, ແລະ ຫ້ອງ A1 ໃນແຜ່ນງານ 2 ມີຄ່າ -6, ທ່ານສາມາດອ້າງອີງທາງອ້ອມໄປຫາຫ້ອງດັ່ງກ່າວໂດຍໃຊ້ຟັງຊັນໃນ B2 ດ້ວຍການປ້ອນ =ABS(INDIRECT(B2)). ຜົນໄດ້ຮັບຈະແມ່ນຄ່າສຳບູນຂອງການອ້າງອີງຫ້ອງທີ່ລະບຸໃນ B2, ເຊິ່ງໃນກໍລະນີນີ້ນັບວ່າແມ່ນ 6.

## AREAS

ສົ່ງຄືນຈຳນວນຂອງຂອບເຂດແຕ່ລະອັນທີ່ຢູ່ໃນຂອບເຂດແບບຫຼາຍອັນ. ຂອບເຂດໜຶ່ງສາມາດປະກອບດ້ວຍຫ້ອງທີ່ຢູ່ຕິດກັນ ຫຼື ພຽງແຕ່ຫ້ອງດຽວກໍໄດ້.

ຟັງຊັນນີ້ຕ້ອງການອາກິວເມັນພຽງອັນດຽວ. ຖ້າທ່ານລະບຸຫຼາຍຂອບເຂດ, ທ່ານຕ້ອງໃສ່ພວກມັນໄວ້ໃນວົງເລັບຕື່ມອີກ. ຫຼາຍຂອບເຂດສາມາດປ້ອນເຂົ້າໄດ້ໂດຍໃຊ້ເຄື່ອງໝາຍຈຳ້ຈຸດ (;) ເປັນຕົວຂັ້ນ, ແຕ່ນີ້ຈະຖືກປ່ຽນເປັນຕົວດຳເນີນການ tilde (~) ໂດຍອັດຕະໂນມັດ. tilde ຖືກໃຊ້ເພື່ອເຊື່ອມຕໍ່ຂອບເຂດເຂົ້າກັນ.

#### ໄວຍາກອນ

AREAS(ການອ້າງອີງ)

Reference ໝາຍເຖິງ ການອ້າງອີງເຖິງຫ້ອງ ຫຼື ຂອບເຂດຫ້ອງ.

#### ຕົວຢ່າງ

=AREAS((A1:B3;F2;G1)) ສົ່ງຄືນ 3, ເນື່ອງຈາກມັນເປັນການອ້າງອີງເຖິງສາມຫ້ອງ ແລະ/ຫຼື ຂອບເຂດ. ຫຼັງຈາກປ້ອນເຂົ້າແລ້ວ ມັນຈະຖືກປ່ຽນເປັນ =AREAS((A1:B3~F2~G1)).

=AREAS(All) ສົ່ງຄືນ 1 ຖ້າທ່ານໄດ້ກຳນົດຂອບເຂດທີ່ຊື່ວ່າ All ໄວ້ໃນ ຂໍ້ມູນ - ກຳນົດຂອບເຂດ.

## CHOOSE

ໃຊ້ດັດຊະນີເພື່ອສົ່ງຄືນຄ່າຈາກລາຍການທີ່ມີໄດ້ສູງສຸດ 30 ຄ່າ.

#### ໄວຍາກອນ

CHOOSE(Index; ຄ່າ 1 [; ຄ່າ 2 [; ... [; ຄ່າ 30]]])

Index ແມ່ນການອ້າງອີງ ຫຼື ຕົວເລກລະຫວ່າງ 1 ຫາ 30 ທີ່ລະບຸວ່າຈະເລືອກເອົາຄ່າໃດຈາກລາຍການ.

ຄ່າ 1, ຄ່າ 2, ..., ຄ່າ 30 ແມ່ນລາຍການຄ່າທີ່ປ້ອນເຂົ້າເປັນການອ້າງອີງຫ້ອງ ຫຼື ເປັນຄ່າແຕ່ລະອັນ.

#### ຕົວຢ່າງ

ຕົວຢ່າງ: =CHOOSE(A1;B1;B2;B3;"Today";"Yesterday";"Tomorrow") ຈະສົ່ງຄືນເນື້ອໃນຂອງຫ້ອງ B2 ຖ້າ A1 = 2; ສຳລັບ A1 = 4, ຟັງຊັນຈະສົ່ງຄືນຂໍ້ຄວາມ "Today".

## COLUMN

ສົ່ງຄືນໝາຍເລກຖັນຂອງການອ້າງອີງຫ້ອງ. ຖ້າການອ້າງອີງແມ່ນຫ້ອງດຽວ, ຈະສົ່ງຄືນໝາຍເລກຖັນຂອງຫ້ອງນັ້ນ; ຖ້າພາຣາມິເຕີແມ່ນຂອບເຂດຫ້ອງ, ໝາຍເລກຖັນທີ່ກົງກັນຈະຖືກສົ່ງຄືນໃນຮູບແບບ ອາເຣ ແຖວດຽວ ຖ້າສູດນັ້ນຖືກປ້ອນເຂົ້າ ເປັນສູດອາເຣ. ຖ້າຟັງຊັນ COLUMN ທີ່ມີການອ້າງອີງຂອບເຂດບໍ່ໄດ້ຖືກໃຊ້ເປັນສູດອາເຣ, ຈະສົ່ງຄືນພຽງແຕ່ໝາຍເລກຖັນຂອງຫ້ອງທຳອິດພາຍໃນຂອບເຂດນັ້ນ.

#### ໄວຍາກອນ

COLUMN([ການອ້າງອີງ])

Reference ແມ່ນການອ້າງອີງເຖິງຫ້ອງ ຫຼື ຂອບເຂດຫ້ອງທີ່ຕ້ອງການຊອກຫາໝາຍເລກຖັນທຳອິດ.

ຖ້າບໍ່ມີການປ້ອນການອ້າງອີງໃດໆ, ຈະສົ່ງຄືນໝາຍເລກຖັນຂອງຫ້ອງທີ່ມີສູດນັ້ນຢູ່. LibreOffice Calc ຈະຕັ້ງການອ້າງອີງໄປຫາຫ້ອງປັດຈຸບັນໂດຍອັດຕະໂນມັດ.

#### ຕົວຢ່າງ

=COLUMN(A1) ເທົ່າກັບ 1. ຖັນ A ແມ່ນຖັນທຳອິດໃນຕາຕະລາງ.

=COLUMN(C3:E3) ເທົ່າກັບ 3. ຖັນ C ແມ່ນຖັນທີສາມໃນຕາຕະລາງ.

=COLUMN(D3:G10) ສົ່ງຄືນ 4 ເພາະວ່າຖັນ D ແມ່ນຖັນທີສີ່ໃນຕາຕະລາງ ແລະ ຟັງຊັນ COLUMN ນີ້ບໍ່ໄດ້ຖືກໃຊ້ເປັນສູດອາເຣ. (ໃນກໍລະນີນີ, ຄ່າທຳອິດຂອງອາເຣຈະຖືກນຳມາໃຊ້ເປັນຜົນໄດ້ຮັບສະເໝີ.)

{=COLUMN(B2:B7)} ແລະ =COLUMN(B2:B7) ທັງສອງຈະສົ່ງຄືນ 2 ເພາະວ່າການອ້າງອີງມີພຽງແຕ່ຖັນ B ເຊິ່ງເປັນຖັນທີສອງໃນຕາຕະລາງ. ເນື່ອງຈາກຂອບເຂດທີ່ມີຖັນດຽວຈະມີໝາຍເລກຖັນດຽວ, ຈຶ່ງບໍ່ມີຄວາມແຕກຕ່າງກັນວ່າຈະໃຊ້ສູດເປັນແບບອາເຣຫຼືບໍ່.

=COLUMN() ສົ່ງຄືນ 3 ຖ້າສູດຖືກປ້ອນເຂົ້າໃນຖັນ C.

{=COLUMN(Rabbit)} ສົ່ງຄືນອາເຣແຖວດຽວ (3, 4) ຖ້າ "Rabbit" ແມ່ນຊື່ຂອບເຂດ (C1:D3).

## COLUMNS

ສົ່ງຄືນຈຳນວນຖັນໃນການອ້າງອີງທີ່ກຳນົດໃຫ້.

#### ໄວຍາກອນ

COLUMNS(ອາເຣ)

Array ແມ່ນການອ້າງອີງເຖິງຂອບເຂດຫ້ອງທີ່ຕ້ອງການຊອກຫາຈຳນວນຖັນທັງໝົດ. ອາກິວເມັນສາມາດເປັນຫ້ອງດຽວກໍໄດ້.

#### ຕົວຢ່າງ

=COLUMNS(B5) ສົ່ງຄືນ 1 ເພາະວ່າຫ້ອງໜຶ່ງປະກອບດ້ວຍຖັນດຽວ.

=COLUMNS(A1:C5) ເທົ່າກັບ 3. ການອ້າງອີງນີ້ປະກອບດ້ວຍສາມຖັນ.

=COLUMNS(Rabbit) ສົ່ງຄືນ 2 ຖ້າ Rabbit ແມ່ນຊື່ຂອບເຂດ (C1:D3).

## DDE

ສົ່ງຄືນຜົນໄດ້ຮັບຂອງການເຊື່ອມຕໍ່ແບບ DDE. ຖ້າເນື້ອໃນຂອງຂອບເຂດ ຫຼື ສ່ວນທີ່ເຊື່ອມຕໍ່ມີການປ່ຽນແປງ, ຄ່າທີ່ສົ່ງຄືນກໍຈະປ່ຽນແປງເຊັ່ນກັນ. ທ່ານຕ້ອງໂຫຼດສະເປຣດຊີດຄືນໃໝ່ ຫຼື ເລືອກ ແກ້ໄຂ - ການເຊື່ອມຕໍ່ ເພື່ອເບິ່ງການອັບເດດການເຊື່ອມຕໍ່. ການເຊື່ອມຕໍ່ຂ້າມລະບົບປະຕິບັດການ, ຕົວຢ່າງຈາກ LibreOffice ທີ່ເຮັດວຽກເທິງ Windows ໄປຫາເອກະສານທີ່ສ້າງຂຶ້ນເທິງ Linux, ແມ່ນບໍ່ໄດ້ຮັບອະນຸຍາດ.

#### ໄວຍາກອນ

DDE("Server"; "File"; "Range" [; Mode])

Server ແມ່ນຊື່ຂອງແອັບພລິເຄຊັນເຊີເວີ. ແອັບພລິເຄຊັນ LibreOffice ຈະມີຊື່ເຊີເວີແມ່ນ "soffice".

File ແມ່ນຊື່ໄຟລ໌ທີ່ສົມບູນ, ລວມທັງການລະບຸທີ່ຢູ່ (path).

Range ແມ່ນຂອບເຂດທີ່ປະກອບດ້ວຍຂໍ້ມູນທີ່ຈະນຳມາປະເມີນຜົນ.

Mode ແມ່ນພາຣາມິເຕີເສີມທີ່ຄວບຄຸມວິທີການທີ່ເຊີເວີ DDE ຈະແປງຂໍ້ມູນໃຫ້ເປັນຕົວເລກ.

ໂໝດ (Mode) | ຜົນທີ່ໄດ້
--- | ---
0 ຫຼື ບໍ່ໄດ້ລະບຸ | ຮູບແບບຕົວເລກຈາກຮູບແບບຫ້ອງ "ເລີ່ມຕົ້ນ"
1 | ຂໍ້ມູນຈະຖືກແປເປັນຮູບແບບມາດຕະຖານສຳລັບພາສາອັງກິດ (ສະຫະລັດ) ສະເໝີ
2 | ຂໍ້ມູນຈະຖືກດຶງມາເປັນຂໍ້ຄວາມ; ບໍ່ມີການແປງເປັນຕົວເລກ

#### ຕົວຢ່າງ

=DDE("soffice";"c:\office\document\data1.ods";"sheet1.A1") ອ່ານເນື້ອໃນຂອງຫ້ອງ A1 ໃນແຜ່ນງານ 1 ຂອງສະເປຣດຊີດ LibreOffice Calc ທີ່ຊື່ວ່າ data1.ods.

=DDE("soffice";"c:\office\document\motto.odt";"Today's motto") ສົ່ງຄ່າຄຳຂວັນໃນຫ້ອງທີ່ມີສູດນີ້. ກ່ອນອື່ນ, ທ່ານຕ້ອງປ້ອນແຖວໜຶ່ງໃນເອກະສານ motto.odt ທີ່ມີຂໍ້ຄວາມຄຳຂວັນ ແລະ ກຳນົດໃຫ້ມັນເປັນແຖວທຳອິດຂອງພາກສ່ວນທີ່ຊື່ວ່າ Today's Motto (ໃນ LibreOffice Writer ພາຍໃຕ້ ແຊກ - ພາກສ່ວນ). ຖ້າຫາກຄຳຂວັນຖືກປ່ຽນແປງ (ແລະ ບັນທຶກ) ໃນເອກະສານ LibreOffice Writer, ຄຳຂວັນຈະຖືກອັບເດດໃນທຸກໆຫ້ອງຂອງ LibreOffice Calc ທີ່ມີການກຳນົດການເຊື່ອມຕໍ່ DDE ນີ້.

## ERRORTYPE

ສົ່ງຄືນຕົວເລກທີ່ກົງກັບ ຄ່າຂໍ້ຜິດພາດ ທີ່ເກີດຂຶ້ນໃນຫ້ອງອື່ນ. ດ້ວຍການຊ່ວຍເຫຼືອຂອງຕົວເລກນີ້, ທ່ານສາມາດສ້າງຂໍ້ຄວາມແຈ້ງຂໍ້ຜິດພາດໄດ້.

ຖ້າມີຂໍ້ຜິດພາດເກີດຂຶ້ນ, ຟັງຊັນຈະສົ່ງຄືນຄ່າຕັກກະສາດ ຫຼື ຄ່າຕົວເລກ.

ແຖບສະຖານະຈະສະແດງລະຫັດຂໍ້ຜິດພາດທີ່ກຳນົດໄວ້ລ່ວງໜ້າຈາກ LibreOffice ຖ້າທ່ານຄລິກໃສ່ຫ້ອງທີ່ມີຂໍ້ຜິດພາດນັ້ນ.

#### ໄວຍາກອນ

ERRORTYPE(ການອ້າງອີງ)

Reference ປະກອບດ້ວຍທີ່ຢູ່ຂອງຫ້ອງທີ່ເກີດຂໍ້ຜິດພາດ.

#### ຕົວຢ່າງ

ຖ້າຫ້ອງ A1 ສະແດງ Err:518, ຟັງຊັນ =ERRORTYPE(A1) ຈະສົ່ງຄືນຕົວເລກ 518.

#### ຂໍ້ມູນທາງເຕັກນິກ

ຟັງຊັນນີ້ ບໍ່ແມ່ນ ສ່ວນໜຶ່ງຂອງມາດຕະຖານ Open Document Format for Office Applications (OpenDocument) ເວີຊັນ 1.3 ພາກທີ 4: ຮູບແບບສູດທີ່ຄິດໄລ່ຄືນໃໝ່ (OpenFormula). ຊື່ພື້ນທີ່ (name space) ແມ່ນ

ORG.OPENOFFICE.ERRORTYPE

## GETPIVOTDATA

ຟັງຊັນ GETPIVOTDATA ສົ່ງຄືນຄ່າຜົນໄດ້ຮັບຈາກຕາຕະລາງພິວອດ. ຄ່ານັ້ນຖືກອ້າງອີງໂດຍໃຊ້ຊື່ຟີວ ແລະ ຊື່ລາຍການ, ດັ່ງນັ້ນມັນຈຶ່ງຍັງໃຊ້ງານໄດ້ເຖິງວ່າຮູບແບບຂອງຕາຕະລາງພິວອດຈະປ່ຽນແປງກໍຕາມ.

#### ໄວຍາກອນ

ສາມາດໃຊ້ຮູບແບບໄວຍາກອນໄດ້ສອງແບບທີ່ແຕກຕ່າງກັນ:

GETPIVOTDATA(TargetField; pivot table[; ຟີວ 1; ລາຍການ 1][; ... [ຟີວ 126; ລາຍການ 126]])

ຫຼື

GETPIVOTDATA(pivot table; ຂໍ້ກຳນົດ)

ໄວຍາກອນແບບທີສອງຈະຖືກນຳມາໃຊ້ຫາກມີການລະບຸພາຣາມິເຕີພຽງສອງອັນ, ເຊິ່ງພາຣາມິເຕີທຳອິດແມ່ນການອ້າງອີງຫ້ອງ ຫຼື ຂອບເຂດຫ້ອງ. ໃນກໍລະນີອື່ນໆ ຈະໃຊ້ໄວຍາກອນແບບທຳອິດ. ຕົວຊ່ວຍສ້າງຟັງຊັນຈະສະແດງໄວຍາກອນແບບທຳອິດ.

### ໄວຍາກອນແບບທຳອິດ

TargetField ແມ່ນຂໍ້ຄວາມທີ່ເລືອກເອົາໜຶ່ງໃນຟີວຂໍ້ມູນຂອງຕາຕະລາງພິວອດ. ຂໍ້ຄວາມນັ້ນສາມາດເປັນຊື່ຂອງຖັນຕົ້ນທາງ, ຫຼື ຊື່ຟີວຂໍ້ມູນຕາມທີ່ສະແດງໃນຕາຕະລາງ (ເຊັ່ນ "Sum - Sales").

pivot table ແມ່ນການອ້າງອີງເຖິງຫ້ອງ ຫຼື ຂອບເຂດຫ້ອງທີ່ຕັ້ງຢູ່ໃນຕາຕະລາງພິວອດ ຫຼື ປະກອບດ້ວຍຕາຕະລາງພິວອດ. ຖ້າຂອບເຂດຫ້ອງມີຕາຕະລາງພິວອດຫຼາຍອັນ, ຈະໃຊ້ຕາຕະລາງທີ່ຖືກສ້າງຂຶ້ນຫຼ້າສຸດ.

ຖ້າບໍ່ມີການລະບຸຄູ່ Field n / Item n, ຈະສົ່ງຄືນຜົນລວມທັງໝົດ. ຖ້າບໍ່ດັ່ງນັ້ນ, ແຕ່ລະຄູ່ຈະເປັນການເພີ່ມຂໍ້ກຳນົດທີ່ຜົນໄດ້ຮັບຕ້ອງສອດຄ່ອງ. Field n ແມ່ນຊື່ຂອງຟີວຈາກຕາຕະລາງພິວອດ. Item n ແມ່ນຊື່ຂອງລາຍການຈາກຟີວນັ້ນ.

ຖ້າຕາຕະລາງພິວອດມີຄ່າຜົນໄດ້ຮັບພຽງອັນດຽວທີ່ກົງກັບຂໍ້ກຳນົດທັງໝົດ, ຫຼື ມີຜົນລວມຍ່ອຍທີ່ສະຫຼຸບຄ່າທີ່ກົງກັນທັງໝົດ, ຜົນໄດ້ຮັບນັ້ນຈະຖືກສົ່ງຄືນ. ຫາກບໍ່ມີຜົນໄດ້ຮັບທີ່ກົງກັນ, ຫຼື ມີຫຼາຍອັນໂດຍບໍ່ມີຜົນລວມຍ່ອຍສຳລັບພວກມັນ, ຈະສົ່ງຄືນຂໍ້ຜິດພາດ. ເງື່ອນໄຂເຫຼົ່ານີ້ໃຊ້ກັບຜົນໄດ້ຮັບທີ່ມີຢູ່ໃນຕາຕະລາງພິວອດ.

ຖ້າຂໍ້ມູນຕົ້ນທາງມີລາຍການທີ່ຖືກເຊື່ອງໄວ້ໂດຍການຕັ້ງຄ່າຂອງຕາຕະລາງພິວອດ, ລາຍການເຫຼົ່ານັ້ນຈະຖືກລະເວັ້ນ. ລຳດັບຂອງຄູ່ ຟີວ/ລາຍການ ແມ່ນບໍ່ສຳຄັນ. ຊື່ຟີວ ແລະ ຊື່ລາຍການແມ່ນບໍ່ແຍກຕົວອັກສອນໃຫຍ່-ນ້ອຍ.

ຖ້າບໍ່ມີການລະບຸຂໍ້ກຳນົດສຳລັບຕົວຕອງ, ຄ່າທີ່ຖືກເລືອກຂອງຟີວນັ້ນຈະຖືກນຳມາໃຊ້ໂດຍປະລິຍາຍ. ຖ້າມີການລະບຸຂໍ້ກຳນົດສຳລັບຕົວຕອງ, ມັນຕ້ອງກົງກັບຄ່າທີ່ຖືກເລືອກຂອງຟີວນັ້ນ, ບໍ່ດັ່ງນັ້ນຈະສົ່ງຄືນຂໍ້ຜິດພາດ. ຕົວຕອງແມ່ນຟີວທີ່ຢູ່ດ້ານເທິງຊ້າຍຂອງຕາຕະລາງພິວອດ, ເຊິ່ງມາຈາກພື້ນທີ່ "ຕົວຕອງ" ໃນໄດອະລັອກຮູບແບບຕາຕະລາງພິວອດ. ໃນແຕ່ລະຕົວຕອງ ສາມາດເລືອກລາຍການ (ຄ່າ) ໄດ້, ເຊິ່ງໝາຍຄວາມວ່າຈະມີພຽງແຕ່ລາຍການນັ້ນທີ່ຖືກນຳມາຄິດໄລ່.

ຄ່າຜົນລວມຍ່ອຍຈາກຕາຕະລາງພິວອດຈະຖືກນຳມາໃຊ້ກໍຕໍ່ເມື່ອພວກມັນໃຊ້ຟັງຊັນ "auto" (ຍົກເວັ້ນເມື່ອມີການລະບຸໃນຂໍ້ກຳນົດ, ເບິ່ງ ໄວຍາກອນແບບທີສອງ ດ້ານລຸ່ມ).

### ໄວຍາກອນແບບທີສອງ

pivot table ມີຄວາມໝາຍຄືກັນກັບໃນໄວຍາກອນແບບທຳອິດ.

Constraints ແມ່ນລາຍການທີ່ຂັ້ນດ້ວຍຍະຫວ່າງ. ແຕ່ລະລາຍການສາມາດໃສ່ເຄື່ອງໝາຍຄຳເວົ້າດ່ຽວ (') ໄດ້. ຂໍ້ຄວາມທັງໝົດຕ້ອງໃສ່ໃນເຄື່ອງໝາຍຄຳເວົ້າຄູ່ ("), ຍົກເວັ້ນແຕ່ທ່ານຈະອ້າງອີງຂໍ້ຄວາມນັ້ນຈາກຫ້ອງອື່ນ.

ໜຶ່ງໃນລາຍການສາມາດເປັນຊື່ຟີວຂໍ້ມູນໄດ້. ສາມາດລະເວັ້ນຊື່ຟີວຂໍ້ມູນໄດ້ຫາກຕາຕະລາງພິວອດມີຟີວຂໍ້ມູນພຽງອັນດຽວ, ແຕ່ຖ້າບໍ່ດັ່ງນັ້ນ ຕ້ອງລະບຸໃຫ້ຊັດເຈນ.

ແຕ່ລະລາຍການອື່ນໆຈະລະບຸຂໍ້ກຳນົດໃນຮູບແບບ ຟີວ[ລາຍການ] (ໂດຍໃຊ້ເຄື່ອງໝາຍ [ ແລະ ]), ຫຼື ລະບຸພຽງແຕ່ ລາຍການ ຫາກຊື່ລາຍການນັ້ນບໍ່ຊຳ້ກັບລາຍການອື່ນໃນທຸກໆຟີວທີ່ໃຊ້ໃນຕາຕະລາງພິວອດ.

ສາມາດເພີ່ມຊື່ຟັງຊັນໃນຮູບແບບ ຟີວ[ລາຍການ;ຟັງຊັນ], ເຊິ່ງຈະເຮັດໃຫ້ຂໍ້ກຳນົດນັ້ນກົງກັບສະເພາະຄ່າຜົນລວມຍ່ອຍທີ່ໃຊ້ຟັງຊັນນັ້ນເທົ່ານັ້ນ. ຊື່ຟັງຊັນທີ່ສາມາດໃຊ້ໄດ້ຄື Sum, Count, Average, Max, Min, Product, Count (ຕົວເລກເທົ່ານັ້ນ), StDev (ຕົວຢ່າງ), StDevP (ປະຊາກອນ), Var (ຕົວຢ່າງ), ແລະ VarP (ປະຊາກອນ), ໂດຍບໍ່ແຍກຕົວອັກສອນໃຫຍ່-ນ້ອຍ.

## HLOOKUP

ຄົ້ນຫາຄ່າ ແລະ ການອ້າງອີງໄປຫາຫ້ອງທີ່ຢູ່ຖັດລົງມາຈາກພື້ນທີ່ທີ່ເລືອກ. ຟັງຊັນນີ້ຈະກວດສອບວ່າແຖວທຳອິດຂອງອາເຣມີຄ່າທີ່ລະບຸຫຼືບໍ່. ຈາກນັ້ນຟັງຊັນຈະສົ່ງຄືນຄ່າໃນແຖວຂອງອາເຣທີ່ລະບຸໃນ ດັດຊະນີ (Index) ໃນຖັນດຽວກັນ.

ການຄົ້ນຫາຮອງຮັບຕົວແທນ (wildcards) ຫຼື ນິພົດປົກກະຕິ (regular expressions). ເມື່ອເປີດໃຊ້ນິພົດປົກກະຕິ, ທ່ານສາມາດປ້ອນ "all.*", ຕົວຢ່າງເພື່ອຊອກຫາຕຳແໜ່ງທຳອິດຂອງ "all" ທີ່ຕາມດ້ວຍຕົວອັກສອນໃດໆ. ຖ້າທ່ານຕ້ອງການຄົ້ນຫາຂໍ້ຄວາມທີ່ເປັນນິພົດປົກກະຕິຄືກັນ, ທ່ານຕ້ອງໃສ່ເຄື່ອງໝາຍ "\" ໄວ້ໜ້າທຸກຕົວອັກສອນພິເສດ ຫຼື ຕົວດຳເນີນການຂອງນິພົດປົກກະຕິ, ຫຼື ກວມເອົາຂໍ້ຄວາມນັ້ນໄວ້ໃນ \Q...\E. ທ່ານສາມາດເປີດ ຫຼື ປິດການປະເມີນອັດຕະໂນມັດຂອງຕົວແທນ ຫຼື ນິພົດປົກກະຕິໄດ້ທີ່ LibreOffice - ຄວາມມັກ ເຄື່ອງມື - ຕົວເລືອກ - LibreOffice Calc - ຄິດໄລ່.

ເມື່ອໃຊ້ຟັງຊັນທີ່ມີອາຄິວເມັ້ນ (argument) ໜຶ່ງ ຫຼື ຫຼາຍກວ່າເປັນຂໍ້ຄວາມເງື່ອນໄຂການຄົ້ນຫາທີ່ສະແດງເຖິງນິພົດປົກກະຕິ, ມັນຈະພະຍາຍາມແປງຂໍ້ຄວາມເງື່ອນໄຂນັ້ນໃຫ້ເປັນຕົວເລກກ່ອນ. ຕົວຢ່າງ, ".0" ຈະຖືກແປງເປັນ 0.0 ແລະ ອື່ນໆ. ຖ້າສຳເລັດ, ການຈັບຄູ່ຈະບໍ່ແມ່ນການຈັບຄູ່ແບບນິພົດປົກກະຕິ ແຕ່ຈະເປັນການຈັບຄູ່ແບບຕົວເລກ. ແນວໃດກໍຕາມ, ເມື່ອປ່ຽນໄປໃຊ້ທ້ອງຖິ່ນ (locale) ທີ່ຕົວຂັ້ນທົດສະນິຍົມບໍ່ແມ່ນຈຸດ ຈະເຮັດໃຫ້ການແປງນິພົດປົກກະຕິເຮັດວຽກໄດ້. ເພື່ອບັງຄັບໃຫ້ມີການປະເມີນເປັນນິພົດປົກກະຕິແທນການສະແດງຜົນແບບຕົວເລກ, ໃຫ້ໃຊ້ບາງນິພົດທີ່ບໍ່ສາມາດຖືກອ່ານຜິດເປັນຕົວເລກໄດ້ ເຊັ່ນ ".[0]" ຫຼື ".\0" ຫຼື "(?i).0".

#### ໄວຍາກອນ

HLOOKUP(Lookup; ອາເຣ; ດັດຊະນີ [; SortedRangeLookup])

ສຳລັບຄຳອະທິບາຍກ່ຽວກັບພາຣາມິເຕີ, ເບິ່ງ: VLOOKUP (ຖັນ ແລະ ແຖວຈະຖືກສະລັບບ່ອນກັນ)

ການຈັດການກັບເຊວວ່າງ

#### ຕົວຢ່າງ

ສົມມຸດວ່າພວກເຮົາໄດ້ສ້າງຕາຕະລາງຖານຂໍ້ມູນຂະໜາດນ້ອຍໃນຂອບເຂດ A1:DO4 ເຊິ່ງປະກອບດ້ວຍຂໍ້ມູນພື້ນຖານກ່ຽວກັບ 118 ທາດເຄມີ. ຖັນທຳອິດປະກອບດ້ວຍຫົວຂໍ້ແຖວຄື “Element”, “Symbol”, “Atomic Number”, ແລະ “Relative Atomic Mass”. ຖັນຕໍ່ໆມາປະກອບດ້ວຍຂໍ້ມູນທີ່ກ່ຽວຂ້ອງຂອງແຕ່ລະທາດ, ຈັດລຽງຈາກຊ້າຍໄປຂວາຕາມໝາຍເລກອາຕອມ. ຕົວຢ່າງ: ຫ້ອງ B1:B4 ປະກອບດ້ວຍ “Hydrogen”, “H”, “1” ແລະ “1.008”, ໃນຂະນະທີ່ຫ້ອງ DO1:DO4 ປະກອບດ້ວຍ “Oganesson”, “Og”, “118”, ແລະ “294”.

| A | B | C | D | ... | DO
--- | --- | --- | --- | --- | --- | ---
1 | ທາດ | ຮີໂດຣແຊນ | ຮີລີອອມ | ລີຕີອອມ | ... | ໂອກາເນັດຊອນ
2 | ສັນຍະລັກ | H | He | Li | ... | Og
3 | ໝາຍເລກອາຕອມ | 1 | 2 | 3 | ... | 118
4 | ມວນສານອາຕອມສຳພັນ | 1.008 | 4.0026 | 6.94 | ... | 294

=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) ສົ່ງຄືນ “Pb”, ເຊິ່ງແມ່ນສັນຍະລັກຂອງທາດກົ່ວ.

=HLOOKUP("Gold"; $A$1:$DO$4; 3; 0) ສົ່ງຄືນ 79, ເຊິ່ງແມ່ນໝາຍເລກອາຕອມຂອງທາດຄຳ.

=HLOOKUP("Carbon"; $A$1:$DO$4; 4; 0) ສົ່ງຄືນ 12.011, ເຊິ່ງແມ່ນມວນສານອາຕອມສຳພັນຂອງທາດກາກບອນ.

## HYPERLINK

ເມື່ອທ່ານຄລິກໃສ່ຫ້ອງທີ່ມີຟັງຊັນ HYPERLINK, ໄຮເປີລິງຈະຖືກເປີດຂຶ້ນ.

ຖ້າທ່ານໃຊ້ພາຣາມິເຕີ CellValue ເສີມ, ສູດຈະຊອກຫາ URL ແລະ ສະແດງຂໍ້ຄວາມ ຫຼື ຕົວເລກອອກມາ.

ເພື່ອເປີດຫ້ອງທີ່ມີໄຮເປີລິງດ້ວຍຄີບອດ, ໃຫ້ເລືອກຫ້ອງນັ້ນ, ກົດ F2 ເພື່ອເຂົ້າສູ່ໂໝດແກ້ໄຂ, ເລື່ອນເຄີເຊີໄປໄວ້ທາງໜ້າໄຮເປີລິງ, ກົດ Shift+F10, ແລ້ວເລືອກ ເປີດໄຮເປີລິງ.

#### ໄວຍາກອນ

HYPERLINK("URL" [; CellValue])

URL ລະບຸເປົ້າໝາຍຂອງລິ້ງ. ພາຣາມິເຕີ CellValue ທີ່ເລືອກໄດ້ແມ່ນຂໍ້ຄວາມ ຫຼື ຕົວເລກທີ່ຈະສະແດງໃນຫ້ອງ ແລະ ຈະຖືກສົ່ງຄືນເປັນຜົນໄດ້ຮັບ. ຖ້າບໍ່ໄດ້ລະບຸພາຣາມິເຕີ CellValue, URL ຈະຖືກສະແດງໃນຂໍ້ຄວາມຂອງຫ້ອງ ແລະ ຈະຖືກສົ່ງຄືນເປັນຜົນໄດ້ຮັບ.

ຕົວເລກ 0 ຈະຖືກສົ່ງຄືນສຳລັບຫ້ອງວ່າງ ແລະ ອົງປະກອບມາຕຣິດ.

#### ຕົວຢ່າງ

=HYPERLINK("http://www.example.org") ສະແດງຂໍ້ຄວາມ "http://www.example.org" ໃນຫ້ອງ ແລະ ຈະເປີດໄຮເປີລິງ http://www.example.org ເມື່ອຖືກຄລິກ.

=HYPERLINK("http://www.example.org";"Click here") ສະແດງຂໍ້ຄວາມ "Click here" ໃນຫ້ອງ ແລະ ຈະເປີດໄຮເປີລິງ http://www.example.org ເມື່ອຖືກຄລິກ.

=HYPERLINK("http://www.example.org";12345) ສະແດງຕົວເລກ 12345 ແລະ ຈະເປີດໄຮເປີລິງ http://www.example.org ເມື່ອຖືກຄລິກ.

=HYPERLINK($B4) ໂດຍທີ່ຫ້ອງ B4 ປະກອບດ້ວຍ http://www.example.org. ຟັງຊັນຈະເພີ່ມ http://www.example.org ເຂົ້າໃນ URL ຂອງຫ້ອງໄຮເປີລິງ ແລະ ສົ່ງຄືນຂໍ້ຄວາມດຽວກັນນັ້ນເປັນຜົນໄດ້ຮັບຂອງສູດ.

=HYPERLINK("http://www.";"Click ") & "example.org" ສະແດງຂໍ້ຄວາມ Click example.org ໃນຫ້ອງ ແລະ ຈະເປີດໄຮເປີລິງ http://www.example.org ເມື່ອຖືກຄລິກ.

=HYPERLINK("#Sheet1.A1";"Go to top") ສະແດງຂໍ້ຄວາມ Go to top ແລະ ຈະໂດດໄປຫາຫ້ອງ Sheet1.A1 ໃນເອກະສານນີ້.

=HYPERLINK("file:///C:/writer.odt#Specification";"Go to Writer bookmark") ສະແດງຂໍ້ຄວາມ "Go to Writer bookmark", ໂຫຼດເອກະສານຂໍ້ຄວາມທີ່ລະບຸ ແລະ ໂດດໄປຫາບຸກມາກ "Specification".

=HYPERLINK("file:///C:/Documents/";"Open Documents folder") ສະແດງຂໍ້ຄວາມ "Open Documents folder" ແລະ ສະແດງເນື້ອໃນຂອງໂຟນເດີໂດຍໃຊ້ຕົວຈັດການໄຟລ໌ມາດຕະຖານໃນລະບົບປະຕິບັດການຂອງທ່ານ.

ຟັງຊັນພະຍາຍາມເຊື່ອມຕໍ່ກັບລັກສະນະສະເພາະຂອງລະບົບ. ຕົວຢ່າງ: "c:\path to\file.ext" ຈະຖືກແປຢ່າງຖືກຕ້ອງເປັນ "file:///c:/path%20to/file.ext" ໃນ Windows, ຫຼື ".." ຈະພາໄປຫາໄດເຣັກທໍຣີແມ່ຂອງເອກະສານ.

## INDEX

INDEX ສົ່ງຄືນການອ້າງອີງ, ຄ່າ ຫຼື ອາເຣຂອງຄ່າຈາກຂອບເຂດການອ້າງອີງ, ເຊິ່ງລະບຸໂດຍໝາຍເລກດັດຊະນີແຖວ ແລະ ຖັນ ຫຼື ອາເຣຂອງດັດຊະນີແຖວ ແລະ ອາເຣຂອງດັດຊະນີຖັນ, ແລະ ດັດຊະນີຂອບເຂດທີ່ເລືອກໄດ້.

INDEX() ຈະສົ່ງຄືນການອ້າງອີງຖ້າອາກິວເມັນແມ່ນການອ້າງອີງໜຶ່ງອັນ ຫຼື ຫຼາຍກວ່ານັ້ນ. ເມື່ອໃຊ້ໃນຫ້ອງໃນຮູບແບບ =INDEX(), ການອ້າງອີງຈະຖືກແກ້ໄຂ ແລະ ສະແດງຄ່າອອກມາ. ເມື່ອ INDEX() ຖືກໃຊ້ໃນອາກິວເມັນຂອງຟັງຊັນອື່ນ, =FUNCTION(INDEX()...), ຟັງຊັນນັ້ນຈະໄດ້ຮັບການອ້າງອີງທີ່ INDEX() ສົ່ງຄືນມາ. ການສົ່ງຄືນການອ້າງອີງແມ່ນແຕກຕ່າງຈາກການສົ່ງຄືນອາເຣຂອງຄ່າ ສຳລັບຟັງຊັນທີ່ຈັດການກັບພວກມັນແຕກຕ່າງກັນ.

#### ໄວຍາກອນ

INDEX(ການອ້າງອີງ [; [ແຖວ] [; [ຖັນ] [; ຂອບເຂດ]]])

Reference ແມ່ນການອ້າງອີງ, ເຊິ່ງປ້ອນເຂົ້າໂດຍກົງ ຫຼື ໂດຍການລະບຸຊື່ຂອບເຂດ. ຖ້າການອ້າງອີງປະກອບດ້ວຍຫຼາຍຂອບເຂດ, ທ່ານຕ້ອງໃສ່ລາຍການການອ້າງອີງ ຫຼື ຊື່ຂອບເຂດໄວ້ໃນວົງເລັບ, ຫຼື ໃຊ້ຕົວດຳເນີນການ tilde (~) ຕົວດຳເນີນການເຊື່ອມຕໍ່ຂອບເຂດ ຫຼື ກຳນົດຊື່ຂອບເຂດທີ່ມີຫຼາຍພື້ນທີ່.

ແຖວ (ເລືອກໄດ້) ໝາຍເຖິງ ແຖວ ຫຼື ອາເຣຂອງດັດຊະນີແຖວຂອງຂອບເຂດການອ້າງອີງທີ່ຕ້ອງການສົ່ງຄືນຄ່າ. ໃນກໍລະນີທີ່ເປັນສູນ ຫຼື ບໍ່ໄດ້ລະບຸ (ບໍ່ມີແຖວສະເພາະ) ແຖວທີ່ອ້າງອີງທັງໝົດຈະຖືກສົ່ງຄືນ.

ຖັນ (ເລືອກໄດ້) ໝາຍເຖິງ ຖັນ ຫຼື ອາເຣຂອງດັດຊະນີຖັນຂອງຂອບເຂດການອ້າງອີງທີ່ຕ້ອງການສົ່ງຄືນຄ່າ. ໃນກໍລະນີທີ່ເປັນສູນ ຫຼື ບໍ່ໄດ້ລະບຸ (ບໍ່ມີຖັນສະເພາະ) ຖັນທີ່ອ້າງອີງທັງໝົດຈະຖືກສົ່ງຄືນ.

ຖ້າ ແຖວ, ຖັນ ຫຼື ທັງສອງຢ່າງຖືກລະເວັ້ນ ຫຼື ຖືກກຳນົດເປັນອາເຣຂອງດັດຊະນີ, ຟັງຊັນ INDEX ຕ້ອງຖືກປ້ອນເຂົ້າເປັນ ຟັງຊັນອາເຣ.

ຂອບເຂດ (ເລືອກໄດ້) ໝາຍເຖິງ ດັດຊະນີຂອງຂອບເຂດຍ່ອຍຫາກມີການອ້າງອີງເຖິງຫຼາຍຂອບເຂດ, ຄ່າເລີ່ມຕົ້ນແມ່ນ 1.

#### ຕົວຢ່າງ

{=INDEX({1,3,5;7,9,10},{2;1},1)} ສົ່ງຄືນອາເຣ 2 ແຖວ ທີ່ປະກອບດ້ວຍ 7 ແລະ 1. ດັດຊະນີແຖວ {2;1} ຈະເລືອກແຖວ 2 ແລ້ວຕາມດ້ວຍແຖວ 1. ດັດຊະນີຖັນ 1 ຈະເລືອກຖັນທຳອິດ.

{=INDEX(D3:G12,{1;2;3;4},{3,1})} ສົ່ງຄືນອາເຣຂະໜາດ 4 ແຖວ ຄູນ 2 ຖັນ. ອາເຣດັດຊະນີແຖວ {1;2;3;4} ເລືອກແຖວທີ 3 ຫາ 6 ແລະ {3,1} ເລືອກຖັນທີສາມ (F) ແລະ ຖັນທຳອິດ (D). ຖັນ 1 ແລະ 3 ຂອງການອ້າງອີງຕົ້ນທາງຈະຖືກສະລັບບ່ອນກັນໃນອາເຣຜົນໄດ້ຮັບ.

=INDEX(Prices;4;1) ສົ່ງຄືນຄ່າຈາກແຖວທີ 4 ແລະ ຖັນທີ 1 ຂອງຂອບເຂດຖານຂໍ້ມູນທີ່ກຳນົດໄວ້ໃນ ຂໍ້ມູນ - ກຳນົດ ເປັນ Prices.

=INDEX(SumX;4;1) ສົ່ງຄືນຄ່າຈາກຂອບເຂດ SumX ໃນແຖວທີ 4 ແລະ ຖັນທີ 1 ຕາມທີ່ກຳນົດໄວ້ໃນ ແຜ່ນງານ - ຂອບເຂດທີ່ຕັ້ງຊື່ ແລະ ນິພົດ - ກຳນົດ.

{=INDEX(A1:B6;1)} ສົ່ງຄືນຄ່າຂອງແຖວທຳອິດຂອງ A1:B6. ໃຫ້ປ້ອນສູດເປັນ ສູດອາເຣ.

{=INDEX(A1:B6;0;1)} ສົ່ງຄືນຄ່າຂອງຖັນທຳອິດຂອງ A1:B6. ໃຫ້ປ້ອນສູດເປັນ ສູດອາເຣ.

=INDEX(A1:B6;1;1) ລະບຸຄ່າໃນຫ້ອງເທິງສຸດເບື້ອງຊ້າຍຂອງຂອບເຂດ A1:B6.

{=INDEX((A1:B6;C1:D6);0;0;2)} ສົ່ງຄືນຄ່າຂອງຂອບເຂດທີສອງ C1:D6 ຈາກຂອບເຂດແບບຫຼາຍອັນ. ໃຫ້ປ້ອນສູດເປັນ ສູດອາເຣ.

ຫົວຂໍ້ທີ່ກ່ຽວຂ້ອງ

ໜ້າວິກິຂອງ INDEX.

## INDIRECT

ສົ່ງຄືນ ການອ້າງອີງ ທີ່ລະບຸໂດຍຂໍ້ຄວາມ. ຟັງຊັນນີ້ຍັງສາມາດໃຊ້ເພື່ອສົ່ງຄືນພື້ນທີ່ຂອງຂໍ້ຄວາມທີ່ກົງກັນໄດ້.

ຟັງຊັນນີ້ຈະຖືກຄຳນວນຄືນໃໝ່ທຸກຄັ້ງເມື່ອມີການຄຳນວນເກີດຂຶ້ນ.

ເພື່ອໃຫ້ໃຊ້ງານຮ່ວມກັນໄດ້ ຟັງຊັນ ADDRESS ແລະ INDIRECT ຮອງຮັບພາຣາມິເຕີເສີມເພື່ອລະບຸວ່າຈະໃຊ້ຮູບແບບການຂຽນທີ່ຢູ່ແບບ R1C1 ແທນຮູບແບບ A1 ປົກກະຕິຫຼືບໍ່.

ໃນ ADDRESS, ພາຣາມິເຕີນີ້ຈະຖືກແຊກເປັນພາຣາມິເຕີທີສີ່, ເຊິ່ງຈະເຮັດໃຫ້ພາຣາມິເຕີຊື່ແຜ່ນງານຍ້າຍໄປຢູ່ຕຳແໜ່ງທີຫ້າ.

ໃນ INDIRECT, ພາຣາມິເຕີນີ້ຈະຖືກເພີ່ມເຂົ້າເປັນພາຣາມິເຕີທີສອງ.

ໃນທັງສອງຟັງຊັນ, ຖ້າປ້ອນອາກິວເມັນເປັນຄ່າ 0, ຈະໃຊ້ຮູບແບບການຂຽນແບບ R1C1. ຖ້າບໍ່ໄດ້ລະບຸ ຫຼື ມີຄ່າອື່ນທີ່ບໍ່ແມ່ນ 0, ຈະໃຊ້ຮູບແບບ A1.

ໃນກໍລະນີທີ່ໃຊ້ຮູບແບບ R1C1, ADDRESS ຈະສົ່ງຄືນຂໍ້ຄວາມທີ່ຢູ່ໂດຍໃຊ້ເຄື່ອງໝາຍອັດສະຈັນ '!' ເປັນຕົວຂັ້ນຊື່ແຜ່ນງານ, ແລະ INDIRECT ກໍຕ້ອງການເຄື່ອງໝາຍອັດສະຈັນເປັນຕົວຂັ້ນຊື່ແຜ່ນງານເຊັ່ນກັນ. ແຕ່ທັງສອງຟັງຊັນຍັງຄົງໃຊ້ເຄື່ອງໝາຍຈຳ້ '.' ເປັນຕົວຂັ້ນຊື່ແຜ່ນງານສຳລັບຮູບແບບ A1.

ເມື່ອເປີດເອກະສານຈາກຮູບແບບ ODF 1.0/1.1, ຟັງຊັນ ADDRESS ທີ່ເຄີຍມີຊື່ແຜ່ນງານເປັນພາຣາມິເຕີທີສີ່ ຈະຍ້າຍຊື່ແຜ່ນງານນັ້ນໄປເປັນພາຣາມິເຕີທີຫ້າ ແລະ ຈະມີພາຣາມິເຕີທີສີ່ໃໝ່ທີ່ມີຄ່າ 1 ຖືກແຊກເຂົ້າມາ.

ເມື່ອບັນທຶກເອກະສານໃນຮູບແບບ ODF 1.0/1.1, ຖ້າຟັງຊັນ ADDRESS ມີພາຣາມິເຕີທີສີ່, ພາຣາມິເຕີນັ້ນຈະຖືກລົບອອກ.

ຢ່າບັນທຶກສະເປຣດຊີດໃນຮູບແບບເກົ່າ ODF 1.0/1.1 ຖ້າພາຣາມິເຕີທີສີ່ໃໝ່ຂອງຟັງຊັນ ADDRESS ຖືກໃຊ້ດ້ວຍຄ່າ 0.

ຟັງຊັນ INDIRECT ຈະຖືກບັນທຶກໂດຍບໍ່ມີການແປງເປັນຮູບແບບ ODF 1.0/1.1. ຖ້າມີພາຣາມິເຕີທີສອງຢູ່, Calc ເວີຊັນເກົ່າຈະສະແດງຂໍ້ຜິດພາດສຳລັບຟັງຊັນນັ້ນ.

#### ໄວຍາກອນ

INDIRECT(ການອ້າງອີງ [; A1])

Ref ໝາຍເຖິງ ການອ້າງອີງເຖິງຫ້ອງ ຫຼື ພື້ນທີ່ (ໃນຮູບແບບຂໍ້ຄວາມ) ທີ່ຕ້ອງການໃຫ້ສົ່ງຄືນເນື້ອໃນ.

A1 (ເລືອກໄດ້) - ຖ້າຕັ້ງເປັນ 0, ຈະໃຊ້ຮູບແບບການຂຽນແບບ R1C1. ຖ້າບໍ່ມີພາຣາມິເຕີນີ ຫຼື ຕັ້ງເປັນຄ່າອື່ນທີ່ບໍ່ແມ່ນ 0, ຈະໃຊ້ຮູບແບບ A1.

ຖ້າທ່ານເປີດສະເປຣດຊີດ Excel ທີ່ໃຊ້ທີ່ຢູ່ທາງອ້ອມເຊິ່ງຄິດໄລ່ມາຈາກຟັງຊັນຂໍ້ຄວາມ, ທີ່ຢູ່ແຜ່ນງານຈະບໍ່ຖືກແປໂດຍອັດຕະໂນມັດ. ຕົວຢ່າງ: ທີ່ຢູ່ Excel ໃນ INDIRECT("[filename]sheetname!"&B1) ຈະບໍ່ຖືກແປງເປັນທີ່ຢູ່ Calc ໃນ INDIRECT("filename#sheetname."&B1).

#### ຕົວຢ່າງ

=INDIRECT(A1) ມີຄ່າເທົ່າກັບ 100 ຖ້າຫ້ອງ A1 ມີຂໍ້ຄວາມ C108 ເປັນການອ້າງອີງ ແລະ ຫ້ອງ C108 ມີຄ່າ 100.

=SUM(INDIRECT("a1:" & ADDRESS(1;3))) ລວມຄ່າໃນຫ້ອງຕັ້ງແຕ່ພື້ນທີ່ A1 ຈົນເຖິງຫ້ອງທີ່ມີທີ່ຢູ່ຕາມທີ່ກຳນົດໂດຍແຖວ 1 ແລະ ຖັນ 3. ນັ້ນໝາຍຄວາມວ່າພື້ນທີ່ A1:C1 ຈະຖືກລວມເຂົ້າກັນ.

ຫົວຂໍ້ທີ່ກ່ຽວຂ້ອງ

ໜ້າວິກິຂອງ INDIRECT.

## MATCH

ສົ່ງຄືນຕຳແໜ່ງສຳພັນຂອງລາຍການໃນອາເຣທີ່ກົງກັບຄ່າທີ່ລະບຸ. ຟັງຊັນຈະສົ່ງຄືນຕຳແໜ່ງຂອງຄ່າທີ່ພົບໃນ lookup_array ເປັນຕົວເລກ.

#### ໄວຍາກອນ

MATCH(Search; LookupArray [; Type])

Search ແມ່ນຄ່າທີ່ຕ້ອງການຄົ້ນຫາໃນອາເຣແບບແຖວດຽວ ຫຼື ຖັນດຽວ.

LookupArray ແມ່ນການອ້າງອີງທີ່ໃຊ້ຄົ້ນຫາ. ອາເຣການຄົ້ນຫາສາມາດເປັນແຖວ ຫຼື ຖັນດຽວ, ຫຼື ສ່ວນໃດສ່ວນໜຶ່ງຂອງແຖວ ຫຼື ຖັນດຽວ.

Type ສາມາດມີຄ່າເປັນ 1, 0, ຫຼື -1. ຖ້າ Type = 1 ຫຼື ຫາກບໍ່ມີພາຣາມິເຕີນີ, ຈະຖືວ່າຖັນທຳອິດຂອງອາເຣຖືກຈັດລຽງຕາມລຳດັບຈາກໜ້ອຍໄປຫາຫຼາຍ. ຖ້າ Type = -1 ຈະຖືວ່າຖັນຖືກຈັດລຽງຕາມລຳດັບຈາກຫຼາຍໄປຫາໜ້ອຍ. ສິ່ງນີ້ກົງກັບຟັງຊັນດຽວກັນໃນ Microsoft Excel.

ຖ້າ Type = 1 ຫຼື ພາຣາມິເຕີທີສາມຫາຍໄປ, ດັດຊະນີຂອງຄ່າສຸດທ້າຍທີ່ມີຄ່ານ້ອຍກວ່າ ຫຼື ເທົ່າກັບເງື່ອນໄຂການຄົ້ນຫາຈະຖືກສົ່ງຄືນ. ສຳລັບ Type = -1, ດັດຊະນີຂອງຄ່າສຸດທ້າຍທີ່ມີຄ່າໃຫຍ່ກວ່າ ຫຼື ເທົ່າກັບຈະຖືກສົ່ງຄືນ.

ຜົນໄດ້ຮັບອາດຈະບໍ່ຖືກຕ້ອງຫາກ Type ມີຄ່າເປັນ -1 ຫຼື +1 ແຕ່ LookupArray ບໍ່ໄດ້ຖືກຈັດລຽງ.

ຖ້າ Type = 0, ຈະຄົ້ນຫາພຽງແຕ່ຄ່າທີ່ກົງກັນພໍດີເທົ່ານັ້ນ. ຖ້າພົບເງື່ອນໄຂການຄົ້ນຫາຫຼາຍກວ່າໜຶ່ງຄັ້ງ, ຟັງຊັນຈະສົ່ງຄືນດັດຊະນີຂອງຄ່າທຳອິດທີ່ກົງກັນ. ສະເພາະກໍລະນີ Type = 0 ເທົ່ານັ້ນທີ່ທ່ານສາມາດຄົ້ນຫາໂດຍໃຊ້ regular expressions (ຖ້າເປີດໃຊ້ໃນຕົວເລືອກການຄິດໄລ່) ຫຼື wildcards (ຖ້າເປີດໃຊ້ໃນຕົວເລືອກການຄິດໄລ່).

ການຄົ້ນຫາຮອງຮັບຕົວແທນ (wildcards) ຫຼື ນິພົດປົກກະຕິ (regular expressions). ເມື່ອເປີດໃຊ້ນິພົດປົກກະຕິ, ທ່ານສາມາດປ້ອນ "all.*", ຕົວຢ່າງເພື່ອຊອກຫາຕຳແໜ່ງທຳອິດຂອງ "all" ທີ່ຕາມດ້ວຍຕົວອັກສອນໃດໆ. ຖ້າທ່ານຕ້ອງການຄົ້ນຫາຂໍ້ຄວາມທີ່ເປັນນິພົດປົກກະຕິຄືກັນ, ທ່ານຕ້ອງໃສ່ເຄື່ອງໝາຍ "\" ໄວ້ໜ້າທຸກຕົວອັກສອນພິເສດ ຫຼື ຕົວດຳເນີນການຂອງນິພົດປົກກະຕິ, ຫຼື ກວມເອົາຂໍ້ຄວາມນັ້ນໄວ້ໃນ \Q...\E. ທ່ານສາມາດເປີດ ຫຼື ປິດການປະເມີນອັດຕະໂນມັດຂອງຕົວແທນ ຫຼື ນິພົດປົກກະຕິໄດ້ທີ່ LibreOffice - ຄວາມມັກ ເຄື່ອງມື - ຕົວເລືອກ - LibreOffice Calc - ຄິດໄລ່.

ເມື່ອໃຊ້ຟັງຊັນທີ່ມີອາຄິວເມັ້ນ (argument) ໜຶ່ງ ຫຼື ຫຼາຍກວ່າເປັນຂໍ້ຄວາມເງື່ອນໄຂການຄົ້ນຫາທີ່ສະແດງເຖິງນິພົດປົກກະຕິ, ມັນຈະພະຍາຍາມແປງຂໍ້ຄວາມເງື່ອນໄຂນັ້ນໃຫ້ເປັນຕົວເລກກ່ອນ. ຕົວຢ່າງ, ".0" ຈະຖືກແປງເປັນ 0.0 ແລະ ອື່ນໆ. ຖ້າສຳເລັດ, ການຈັບຄູ່ຈະບໍ່ແມ່ນການຈັບຄູ່ແບບນິພົດປົກກະຕິ ແຕ່ຈະເປັນການຈັບຄູ່ແບບຕົວເລກ. ແນວໃດກໍຕາມ, ເມື່ອປ່ຽນໄປໃຊ້ທ້ອງຖິ່ນ (locale) ທີ່ຕົວຂັ້ນທົດສະນິຍົມບໍ່ແມ່ນຈຸດ ຈະເຮັດໃຫ້ການແປງນິພົດປົກກະຕິເຮັດວຽກໄດ້. ເພື່ອບັງຄັບໃຫ້ມີການປະເມີນເປັນນິພົດປົກກະຕິແທນການສະແດງຜົນແບບຕົວເລກ, ໃຫ້ໃຊ້ບາງນິພົດທີ່ບໍ່ສາມາດຖືກອ່ານຜິດເປັນຕົວເລກໄດ້ ເຊັ່ນ ".[0]" ຫຼື ".\0" ຫຼື "(?i).0".

#### ຕົວຢ່າງ

=MATCH(200;D1:D100) ຄົ້ນຫາຄ່າ 200 ໃນພື້ນທີ່ D1:D100 ເຊິ່ງຖືກຈັດລຽງຕາມຖັນ D. ເມື່ອພົບຄ່ານີ, ໝາຍເລກແຖວທີ່ພົບຈະຖືກສົ່ງຄືນ. ຖ້າພົບຄ່າທີ່ສູງກວ່າໃນລະຫວ່າງການຄົ້ນຫາໃນຖັນ, ໝາຍເລກຂອງແຖວກ່ອນໜ້ານັ້ນຈະຖືກສົ່ງຄືນ.

## OFFSET

ສົ່ງຄືນຄ່າຂອງຫ້ອງທີ່ຖັດອອກໄປຕາມຈຳນວນແຖວ ແລະ ຖັນທີ່ກຳນົດຈາກຈຸດອ້າງອີງ.

ຟັງຊັນນີ້ຈະຖືກຄຳນວນຄືນໃໝ່ທຸກຄັ້ງເມື່ອມີການຄຳນວນເກີດຂຶ້ນ.

#### ໄວຍາກອນ

OFFSET(ການອ້າງອີງ; ແຖວ; ຖັນ [; ຄວາມສູງ [; ຄວາມກວ້າງ]])

Reference ແມ່ນຈຸດອ້າງອີງທີ່ຟັງຊັນຈະເລີ່ມຕົ້ນຄົ້ນຫາການອ້າງອີງໃໝ່.

Rows ແມ່ນຈຳນວນແຖວທີ່ການອ້າງອີງຖືກເລື່ອນຂຶ້ນ (ຄ່າລົບ) ຫຼື ເລື່ອນລົງ. ໃຊ້ 0 ເພື່ອໃຫ້ຢູ່ແຖວເດີມ.

Columns ແມ່ນຈຳນວນຖັນທີ່ການອ້າງອີງຖືກເລື່ອນໄປທາງຊ້າຍ (ຄ່າລົບ) ຫຼື ໄປທາງຂວາ. ໃຊ້ 0 ເພື່ອໃຫ້ຢູ່ຖັນເດີມ.

Height (ເລືອກໄດ້) ແມ່ນຄວາມສູງຕາມແນວຕັ້ງສຳລັບພື້ນທີ່ທີ່ເລີ່ມຕົ້ນຈາກຕຳແໜ່ງອ້າງອີງໃໝ່.

Width (ເລືອກໄດ້) ແມ່ນຄວາມກວ້າງຕາມແນວນອນສຳລັບພື້ນທີ່ທີ່ເລີ່ມຕົ້ນຈາກຕຳແໜ່ງອ້າງອີງໃໝ່.

ອາກິວເມັນ Rows ແລະ Columns ຕ້ອງບໍ່ພາໄປຫາແຖວ ຫຼື ຖັນເລີ່ມຕົ້ນທີ່ເປັນສູນ ຫຼື ຄ່າລົບ.

ອາກິວເມັນ Height ແລະ Width ຕ້ອງບໍ່ພາໄປຫາຈຳນວນແຖວ ຫຼື ຖັນທີ່ເປັນສູນ ຫຼື ຄ່າລົບ.

ໃນຟັງຊັນ LibreOffice Calc, ພາລາມິເຕີທີ່ຖືກໝາຍວ່າ "ເລືອກໄດ້" ສາມາດຖືກລະເວັ້ນໄດ້ກໍຕໍ່ເມື່ອບໍ່ມີພາລາມິເຕີອື່ນຕາມຫຼັງເທົ່ານັ້ນ. ຕົວຢ່າງ, ໃນຟັງຊັນທີ່ມີສີ່ພາລາມິເຕີ, ເຊິ່ງສອງພາລາມິເຕີສຸດທ້າຍຖືກໝາຍວ່າ "ເລືອກໄດ້", ທ່ານສາມາດລະເວັ້ນພາລາມິເຕີທີ 4 ຫຼື ພາລາມິເຕີທີ 3 ແລະ 4 ໄດ້, ແຕ່ທ່ານບໍ່ສາມາດລະເວັ້ນພາລາມິເຕີທີ 3 ພຽງຢ່າງດຽວໄດ້.

#### ຕົວຢ່າງ

=OFFSET(A1;2;2) ສົ່ງຄືນຄ່າໃນຫ້ອງ C3 (ຫ້ອງ A1 ທີ່ເລື່ອນລົງສອງແຖວ ແລະ ໄປທາງຂວາສອງຖັນ). ຖ້າຫ້ອງ C3 ມີຄ່າ 100 ຟັງຊັນນີ້ຈະສົ່ງຄືນຄ່າ 100.

=OFFSET(B2:C3;1;1) ສົ່ງຄືນການອ້າງອີງເຖິງ B2:C3 ທີ່ເລື່ອນລົງໜຶ່ງແຖວ ແລະ ໄປທາງຂວາໜຶ່ງຖັນ (C3:D4).

=OFFSET(B2:C3;-1;-1) ສົ່ງຄືນການອ້າງອີງເຖິງ B2:C3 ທີ່ເລື່ອນຂຶ້ນໜຶ່ງແຖວ ແລະ ໄປທາງຊ້າຍໜຶ່ງຖັນ (A1:B2).

=OFFSET(B2:C3;0;0;3;4) ສົ່ງຄືນການອ້າງອີງເຖິງ B2:C3 ທີ່ຖືກປັບຂະໜາດເປັນ 3 ແຖວ ແລະ 4 ຖັນ (B2:E4).

=OFFSET(B2:C3;1;0;3;4) ສົ່ງຄືນການອ້າງອີງເຖິງ B2:C3 ທີ່ເລື່ອນລົງໜຶ່ງແຖວ ແລະ ປັບຂະໜາດເປັນ 3 ແຖວ ແລະ 4 ຖັນ (B3:E5).

=SUM(OFFSET(A1;2;2;5;6)) ຄິດໄລ່ຜົນລວມຂອງພື້ນທີ່ທີ່ເລີ່ມຕົ້ນຈາກຫ້ອງ C3 ແລະ ມີຄວາມສູງ 5 ແຖວ ແລະ ຄວາມກວ້າງ 6 ຖັນ (ພື້ນທີ່ = C3:H7).

ຖ້າຫາກກຳນົດ ຄວາມກວ້າງ ຫຼື ຄວາມສູງ, ຟັງຊັນ OFFSET ຈະສົ່ງຄ່າການອ້າງອີງໄລຍະຫ້ອງຄືນມາ. ຖ້າຫາກ ການອ້າງອີງ ແມ່ນການອ້າງອີງຫ້ອງດຽວ ແລະ ທັງ ຄວາມກວ້າງ ແລະ ຄວາມສູງ ຖືກລະເວັ້ນໄວ້, ມັນຈະສົ່ງຄ່າການອ້າງອີງຫ້ອງດຽວຄືນມາ.

## ROW

ສົ່ງຄືນໝາຍເລກແຖວຂອງການອ້າງອີງຫ້ອງ. ຖ້າການອ້າງອີງແມ່ນຫ້ອງດຽວ, ຈະສົ່ງຄືນໝາຍເລກແຖວຂອງຫ້ອງນັ້ນ. ຖ້າການອ້າງອີງແມ່ນຂອບເຂດຫ້ອງ, ຈະສົ່ງຄືນໝາຍເລກແຖວທີ່ກົງກັນໃນຮູບແບບ ອາເຣ ຖັນດຽວ ຖ້າສູດນັ້ນຖືກປ້ອນເຂົ້າ ເປັນສູດອາເຣ. ຖ້າຟັງຊັນ ROW ທີ່ມີການອ້າງອີງຂອບເຂດບໍ່ໄດ້ຖືກໃຊ້ໃນສູດອາເຣ, ຈະສົ່ງຄືນພຽງແຕ່ໝາຍເລກແຖວຂອງຫ້ອງທຳອິດໃນຂອບເຂດນັ້ນ.

#### ໄວຍາກອນ

ROW([ການອ້າງອີງ])

Reference ແມ່ນຫ້ອງ, ພື້ນທີ່ ຫຼື ຊື່ຂອງພື້ນທີ່.

ຖ້າທ່ານບໍ່ລະບຸການອ້າງອີງ, ຈະສົ່ງຄືນໝາຍເລກແຖວຂອງຫ້ອງທີ່ມີສູດນັ້ນຢູ່. LibreOffice Calc ຈະຕັ້ງການອ້າງອີງໄປຫາຫ້ອງປັດຈຸບັນໂດຍອັດຕະໂນມັດ.

#### ຕົວຢ່າງ

=ROW(B3) ສົ່ງຄືນ 3 ເພາະວ່າການອ້າງອີງໝາຍເຖິງແຖວທີສາມໃນຕາຕະລາງ.

{=ROW(D5:D8)} ສົ່ງຄືນອາເຣຖັນດຽວ (5, 6, 7, 8) ເພາະວ່າການອ້າງອີງທີ່ລະບຸປະກອບດ້ວຍແຖວທີ 5 ຫາ 8.

=ROW(D5:D8) ສົ່ງຄືນ 5 ເພາະວ່າຟັງຊັນ ROW ນີ້ບໍ່ໄດ້ຖືກໃຊ້ເປັນສູດອາເຣ ແລະ ຈະສົ່ງຄືນພຽງແຕ່ໝາຍເລກຂອງແຖວທຳອິດຂອງການອ້າງອີງ.

{=ROW(A1:E1)} ແລະ =ROW(A1:E1) ທັງສອງຈະສົ່ງຄືນ 1 ເພາະວ່າການອ້າງອີງມີພຽງແຕ່ແຖວ 1 ເຊິ່ງເປັນແຖວທຳອິດໃນຕາຕະລາງ. (ເນື່ອງຈາກຂອບເຂດທີ່ມີແຖວດຽວຈະມີໝາຍເລກແຖວດຽວ, ຈຶ່ງບໍ່ມີຄວາມແຕກຕ່າງກັນວ່າຈະໃຊ້ສູດເປັນແບບອາເຣຫຼືບໍ່.)

=ROW() ສົ່ງຄືນ 3 ຖ້າສູດຖືກປ້ອນເຂົ້າໃນແຖວ 3.

{=ROW(Rabbit)} ສົ່ງຄືນອາເຣຖັນດຽວ (1, 2, 3) ຖ້າ "Rabbit" ແມ່ນຊື່ຂອບເຂດ (C1:D3).

## ROWS

ສົ່ງຄືນຈຳນວນແຖວໃນການອ້າງອີງ ຫຼື ອາເຣ.

#### ໄວຍາກອນ

ROWS(ອາເຣ)

Array ແມ່ນການອ້າງອີງ ຫຼື ຊື່ພື້ນທີ່ທີ່ຕ້ອງການຊອກຫາຈຳນວນແຖວທັງໝົດ.

#### ຕົວຢ່າງ

=Rows(B5) ສົ່ງຄືນ 1 ເພາະວ່າຫ້ອງໜຶ່ງປະກອບດ້ວຍແຖວດຽວ.

=ROWS(A10:B12) ສົ່ງຄືນ 3.

=ROWS(Rabbit) ສົ່ງຄືນ 3 ຖ້າ "Rabbit" ແມ່ນຊື່ຂອບເຂດ (C1:D3).

## SHEET

ສົ່ງຄືນໝາຍເລກແຜ່ນງານຂອງການອ້າງອີງ ຫຼື ຂໍ້ຄວາມທີ່ລະບຸຊື່ແຜ່ນງານ. ຖ້າທ່ານບໍ່ປ້ອນພາຣາມິເຕີໃດໆ, ຜົນໄດ້ຮັບຈະແມ່ນໝາຍເລກແຜ່ນງານຂອງສະເປຣດຊີດທີ່ມີສູດນັ້ນຢູ່.

#### ໄວຍາກອນ

SHEET([ການອ້າງອີງ])

Reference ແມ່ນພາຣາມິເຕີເສີມ ແລະ ເປັນການອ້າງອີງເຖິງຫ້ອງ, ພື້ນທີ່ ຫຼື ຂໍ້ຄວາມຊື່ແຜ່ນງານ.

#### ຕົວຢ່າງ

=SHEET(Sheet2.A1) ສົ່ງຄືນ 2 ຖ້າ Sheet2 ແມ່ນແຜ່ນງານທີສອງໃນເອກະສານສະເປຣດຊີດ.

=SHEET("Sheet3") ສົ່ງຄືນ 3 ຖ້າ Sheet3 ແມ່ນແຜ່ນງານທີສາມໃນເອກະສານສະເປຣດຊີດ.

## SHEETS

ກຳນົດຈຳນວນແຜ່ນງານໃນການອ້າງອີງ. ຖ້າທ່ານບໍ່ປ້ອນພາຣາມິເຕີໃດໆ, ມັນຈະສົ່ງຄືນຈຳນວນແຜ່ນງານທັງໝົດໃນເອກະສານປັດຈຸບັນ.

#### ໄວຍາກອນ

SHEETS([ການອ້າງອີງ])

Reference ແມ່ນການອ້າງອີງເຖິງແຜ່ນງານ ຫຼື ພື້ນທີ່. ພາຣາມິເຕີນີແມ່ນເລືອກໄດ້.

#### ຕົວຢ່າງ

=SHEETS(Sheet1.A1:Sheet3.G12) ສົ່ງຄືນ 3 ຖ້າ Sheet1, Sheet2, ແລະ Sheet3 ມີຢູ່ຕາມລຳດັບທີ່ລະບຸ.

## VLOOKUP

ຄົ້ນຫາຕາມແນວຕັ້ງໂດຍອ້າງອີງໃສ່ຫ້ອງທີ່ຢູ່ຕິດກັນທາງດ້ານຂວາ. ຟັງຊັນນີ້ຈະກວດສອບວ່າຄ່າທີ່ລະບຸມີຢູ່ໃນຖັນທຳອິດຂອງອາເຣຫຼືບໍ່. ຈາກນັ້ນຟັງຊັນຈະສົ່ງຄືນຄ່າໃນແຖວດຽວກັນຈາກຖັນທີ່ລະບຸໂດຍ ດັດຊະນີ (Index). ຖ້າພາຣາມິເຕີ SortedRangeLookup ຖືກລະເວັ້ນ ຫຼື ຕັ້ງເປັນ TRUE ຫຼື ໜຶ່ງ, ຈະຖືວ່າຂໍ້ມູນຖືກຈັດລຽງຕາມລຳດັບຈາກໜ້ອຍໄປຫາຫຼາຍ. ໃນກໍລະນີນີ, ຫາກບໍ່ພົບຄ່າ Lookup ທີ່ກົງກັນພໍດີ, ຈະສົ່ງຄືນຄ່າສຸດທ້າຍທີ່ມີຄ່ານ້ອຍກວ່າເງື່ອນໄຂ. ຖ້າ SortedRangeLookup ຖືກຕັ້ງເປັນ FALSE ຫຼື ສູນ, ຕ້ອງພົບຄ່າທີ່ກົງກັນພໍດີເທົ່ານັ້ນ, ຖ້າບໍ່ດັ່ງນັ້ນຈະສົ່ງຄືນຂໍ້ຜິດພາດ Error: Value Not Available. ດັ່ງນັ້ນ, ຖ້າໃຊ້ຄ່າເປັນສູນ ຂໍ້ມູນກໍບໍ່ຈຳເປັນຕ້ອງຈັດລຽງຕາມລຳດັບ.

ການຄົ້ນຫາຮອງຮັບຕົວແທນ (wildcards) ຫຼື ນິພົດປົກກະຕິ (regular expressions). ເມື່ອເປີດໃຊ້ນິພົດປົກກະຕິ, ທ່ານສາມາດປ້ອນ "all.*", ຕົວຢ່າງເພື່ອຊອກຫາຕຳແໜ່ງທຳອິດຂອງ "all" ທີ່ຕາມດ້ວຍຕົວອັກສອນໃດໆ. ຖ້າທ່ານຕ້ອງການຄົ້ນຫາຂໍ້ຄວາມທີ່ເປັນນິພົດປົກກະຕິຄືກັນ, ທ່ານຕ້ອງໃສ່ເຄື່ອງໝາຍ "\" ໄວ້ໜ້າທຸກຕົວອັກສອນພິເສດ ຫຼື ຕົວດຳເນີນການຂອງນິພົດປົກກະຕິ, ຫຼື ກວມເອົາຂໍ້ຄວາມນັ້ນໄວ້ໃນ \Q...\E. ທ່ານສາມາດເປີດ ຫຼື ປິດການປະເມີນອັດຕະໂນມັດຂອງຕົວແທນ ຫຼື ນິພົດປົກກະຕິໄດ້ທີ່ LibreOffice - ຄວາມມັກ ເຄື່ອງມື - ຕົວເລືອກ - LibreOffice Calc - ຄິດໄລ່.

ເມື່ອໃຊ້ຟັງຊັນທີ່ມີອາຄິວເມັ້ນ (argument) ໜຶ່ງ ຫຼື ຫຼາຍກວ່າເປັນຂໍ້ຄວາມເງື່ອນໄຂການຄົ້ນຫາທີ່ສະແດງເຖິງນິພົດປົກກະຕິ, ມັນຈະພະຍາຍາມແປງຂໍ້ຄວາມເງື່ອນໄຂນັ້ນໃຫ້ເປັນຕົວເລກກ່ອນ. ຕົວຢ່າງ, ".0" ຈະຖືກແປງເປັນ 0.0 ແລະ ອື່ນໆ. ຖ້າສຳເລັດ, ການຈັບຄູ່ຈະບໍ່ແມ່ນການຈັບຄູ່ແບບນິພົດປົກກະຕິ ແຕ່ຈະເປັນການຈັບຄູ່ແບບຕົວເລກ. ແນວໃດກໍຕາມ, ເມື່ອປ່ຽນໄປໃຊ້ທ້ອງຖິ່ນ (locale) ທີ່ຕົວຂັ້ນທົດສະນິຍົມບໍ່ແມ່ນຈຸດ ຈະເຮັດໃຫ້ການແປງນິພົດປົກກະຕິເຮັດວຽກໄດ້. ເພື່ອບັງຄັບໃຫ້ມີການປະເມີນເປັນນິພົດປົກກະຕິແທນການສະແດງຜົນແບບຕົວເລກ, ໃຫ້ໃຊ້ບາງນິພົດທີ່ບໍ່ສາມາດຖືກອ່ານຜິດເປັນຕົວເລກໄດ້ ເຊັ່ນ ".[0]" ຫຼື ".\0" ຫຼື "(?i).0".

#### ໄວຍາກອນ

=VLOOKUP(Lookup; ອາເຣ; ດັດຊະນີ [; SortedRangeLookup])

Lookup ແມ່ນຄ່າປະເພດໃດກໍໄດ້ທີ່ຕ້ອງການຄົ້ນຫາໃນຖັນທຳອິດຂອງອາເຣ.

Array ແມ່ນການອ້າງອີງ, ເຊິ່ງຕ້ອງມີຈຳນວນຖັນຢ່າງໜ້ອຍເທົ່າກັບໝາຍເລກທີ່ລະບຸໃນອາກິວເມັນ ດັດຊະນີ (Index).

Index ແມ່ນໝາຍເລກຖັນໃນອາເຣທີ່ປະກອບດ້ວຍຄ່າທີ່ຕ້ອງການໃຫ້ສົ່ງຄືນ. ຖັນທຳອິດມີໝາຍເລກ 1.

SortedRangeLookup ແມ່ນພາຣາມິເຕີເສີມທີ່ລະບຸວ່າຖັນທຳອິດໃນອາເຣປະກອບດ້ວຍຂອບເຂດຂອງຄ່າແທນທີ່ຈະເປັນຄ່າປົກກະຕິຫຼືບໍ່. ໃນໂໝດນີ້, ການຄົ້ນຫາຈະສົ່ງຄືນຄ່າໃນແຖວທີ່ຖັນທຳອິດມີຄ່າເທົ່າກັບ ຫຼື ໜ້ອຍກວ່າ Lookup. ຕົວຢ່າງ: ມັນອາດຈະປະກອບດ້ວຍວັນທີທີ່ມີການປ່ຽນແປງຄ່າພາສີ, ດັ່ງນັ້ນຄ່າຕ່າງໆຈຶ່ງໝາຍເຖິງວັນທີເລີ່ມຕົ້ນຂອງໄລຍະເວລາທີ່ຄ່າພາສີນັ້ນມີຜົນບັງຄັບໃຊ້. ດັ່ງນັ້ນ, ການຄົ້ນຫາວັນທີທີ່ບໍ່ມີຢູ່ໃນຖັນທຳອິດ ແຕ່ຢູ່ລະຫວ່າງວັນທີທີ່ກຳນົດໄວ້ ຈະສົ່ງຄືນຄ່າທີ່ຕຳ່ກວ່າ, ເຮັດໃຫ້ສາມາດຊອກຫາຂໍ້ມູນທີ່ມີຜົນໃນວັນທີທີ່ຄົ້ນຫານັ້ນໄດ້. ໃຫ້ປ້ອນຄ່າບູລີນ FALSE ຫຼື ສູນ ຖ້າຖັນທຳອິດບໍ່ແມ່ນລາຍການຂອບເຂດ. ເມື່ອພາຣາມິເຕີນີເປັນ TRUE ຫຼື ບໍ່ໄດ້ລະບຸ, ຖັນທຳອິດໃນອາເຣ ຕ້ອງຖືກຈັດລຽງຕາມລຳດັບຈາກໜ້ອຍໄປຫາຫຼາຍ. ຖັນທີ່ຈັດລຽງແລ້ວຈະຄົ້ນຫາໄດ້ໄວຂຶ້ນ ແລະ ຟັງຊັນຈະສົ່ງຄືນຄ່າສະເໝີ ເຖິງວ່າຈະບໍ່ພົບຄ່າທີ່ກົງກັນພໍດີກໍຕາມ ຫາກຄ່ານັ້ນໃຫຍ່ກວ່າຄ່າທີ່ຕຳ່ສຸດໃນລາຍການ. ສຳລັບລາຍການທີ່ບໍ່ໄດ້ຈັດລຽງ, ຄ່າທີ່ຄົ້ນຫາຕ້ອງກົງກັນພໍດີ ເພາະຖ້າບໍ່ດັ່ງນັ້ນຟັງຊັນຈະສົ່ງຄືນ #N/A ພ້ອມຂໍ້ຄວາມ: Error: Value Not Available.

ການຈັດການກັບເຊວວ່າງ

#### ຕົວຢ່າງ

ທ່ານຕ້ອງການປ້ອນໝາຍເລກອາຫານໃນເມນູລົງໃນຫ້ອງ A1, ແລະ ໃຫ້ຊື່ຂອງອາຫານນັ້ນສະແດງເປັນຂໍ້ຄວາມໃນຫ້ອງຂ້າງໆ (B1) ທັນທີ. ການກຳນົດໝາຍເລກໃຫ້ກົງກັບຊື່ແມ່ນຢູ່ໃນອາເຣ D1:E100. ໂດຍຫ້ອງ D1 ປະກອບດ້ວຍ 100, ຫ້ອງ E1 ປະກອບດ້ວຍຊື່ ແກງຜັກ, ແລະ ຕໍ່ໆໄປສຳລັບລາຍການອາຫານ 100 ຢ່າງ. ຕົວເລກໃນຖັນ D ຖືກຈັດລຽງຕາມລຳດັບແລ້ວ; ດັ່ງນັ້ນ, ພາຣາມິເຕີ Sorted ຈຶ່ງບໍ່ຈຳເປັນ.

ປ້ອນສູດຕໍ່ໄປນີ້ໃນ B1:

=VLOOKUP(A1;D1:E100;2)

ທັນທີທີ່ທ່ານປ້ອນຕົວເລກໃນ A1, ຫ້ອງ B1 ຈະສະແດງຂໍ້ຄວາມທີ່ກົງກັນຈາກຖັນທີສອງຂອງການອ້າງອີງ D1:E100. ການປ້ອນຕົວເລກທີ່ບໍ່ມີຢູ່ໃນລາຍການຈະສະແດງຂໍ້ຄວາມຂອງຕົວເລກທີ່ຖັດລົງມາ. ເພື່ອປ້ອງກັນສິ່ງນີ້, ໃຫ້ປ້ອນ FALSE ເປັນພາຣາມິເຕີສຸດທ້າຍໃນສູດ ເພື່ອໃຫ້ມັນສະແດງຂໍ້ຄວາມຂໍ້ຜິດພາດເມື່ອມີການປ້ອນຕົວເລກທີ່ບໍ່ມີຢູ່ໃນລາຍການ.

ຫົວຂໍ້ທີ່ກ່ຽວຂ້ອງ

ຟັງຊັນຕາມໝວດໝູ່

ກະລຸນາສະໜັບສະໜູນພວກເຮົາ!