Sumário

# Função AGREGAR

Esta função retorna o resultado agregado de cálculos de um intervalo. A função AGREGAR permite ignorar linhas ocultas e valores de erro, bem como agregar outras funções, tais como aquelas que são listadas abaixo.

A função AGREGAR é aplicada a intervalos verticais com autofiltro ativado. Se o autofiltro não estiver ativado, o cálculo automático da função não funciona para linhas ocultas recentemente. Esta função não foi feita para operar em intervalos horizontais, mas pode ser aplicada a eles também, com limitações. Em particular a função AGREGAR aplicada a um intervalo de dados horizontal não reconhece as colunas ocultas, porém omite corretamente os erros e resultados da função SUBTOTAL e outras funções AGREGAR incorporadas numa linha.

### Sintaxe

AGREGAR(Função; Opção; Número 1[; Número 2][; … ;[Número 253]])

ou

AGREGAR (Função; Opção; Matriz[;k])

Função – argumento obrigatório. Um número ou uma referência a uma célula, com valor de 1 a 19, de acordo com a seguinte tabela.

Índice de funções | Função aplicada
--- | ---
1 | MÉDIA
2 | CONT.NÚM
3 | CONT.VALORES
4 | MÁXIMO
5 | MÍNIMO
6 | MULT
7 | DESVPAD.S
8 | DESVPAD.P
9 | SOMA
10 | VAR.S
11 | VAR.P
12 | MED
13 | MODO.ÚNICO
14 | MAIOR
15 | MENOR
16 | PERCENTIL.INC
17 | QUARTIL.INC
18 | PERCENTIL.EXC
19 | QUARTIL.EXC

Para argumentos inteiros, valores não inteiros são truncados para inteiro.

Opção – argumento obrigatório. Um índice da opção, ou referência a uma célula, com valor de 0 a 7 que determina as partes a ignorar no intervalo para a função.

Índice da opção | Opção aplicada
--- | ---
0 | Ignorar somente funções SUBTOTAL e AGREGAR incorporadas
1 | Ignorar somente linhas ocultas, funções SUBTOTAL e AGREGAR incorporadas
2 | Ignorar somente erros, funções SUBTOTAL e AGREGAR incorporadas
3 | Ignorar somente linhas ocultas, erros, funções SUBTOTAL e AGREGAR incorporadas
4 | Ignorar nada
5 | Ignorar somente linhas ocultas
6 | Ignorar somente erros
7 | Ignorar somente linhas ocultas e erros

Para argumentos inteiros, valores não inteiros são truncados para inteiro.

Número 1 – argumento obrigatório. O primeiro argumento numérico (se o intervalo for definido por uma lista de valores dentro da função) ou uma referência a uma célula que o contém.

Número2, 3, ... – opcional. Um argumento numérico ou referencia a uma célula (até 253 argumentos), com os valores a agregar.

Matriz – argumento obrigatório. A matriz pode ser especificada pelos limites do intervalo, pelo nome do intervalo nomeado, ou rótulo de coluna.

Para utilizar rótulos de colunas, a opção "Localizar rótulos de colunas e linhas automaticamente" deve estar ativada.

k - argumento obrigatório para as seguintes funções MAIOR, MENOR, PERCENTIL.INC, QUARTIL.INC, PERCENTIL.EXC, QUARTIL.EXC. É um argumento numérico, que deve corresponder ao segundo argumento destas funções.

### Exemplos

| A | B | C
1 | ColunaUm | ColunaDois | ColunaTres
2 | 34 | 11 | 12
3 | 10 | 56 | 35
4 | #DIV/0! | 5 | 3
5 | 20 | 8 | 1
6 | 0 | 8 | 9
7 | #VALOR! | 20 | 21
8 | 5 | 7 | 8
9 | 14 | 0 | 5

=AGREGAR(4;2;A2:A9)
Retorna o valor máximo no intervalo A2:A9 = 34.

=AGREGAR(9;5;A5:C5)
Retorna a soma para o intervalo A5:C5 = 29, mesmo que algumas colunas estejam ocultas.

=AGREGAR(9;5;B2:B9)
Retorna a soma da coluna B = 115. Se houver uma linha oculta, a função omite seu valor, por exemplo, se a 7ª linha estiver oculta, a função retorna 95.

Se precisar aplicar a função num intervalo com três dimensões, este exemplo mostra como fazer.

=AGREGAR(13;3;Planilha1.B2:B9:Planilha3.B2:B9)
Retorna a função modo dos valores da segunda coluna através das planilhas 1:3 (que tem os mesmos dados) =8.

Pode-se utilizar referências a células ou a intervalos para cada argumento na fórmula. O exemplo a seguir mostra como isso funciona. Ademais, mostra que é possível usar rótulos de colunas para especificar uma matriz.

=AGREGAR(E3;E5;'ColunaUm')
Se E3 = 13 e E5 = 5, a função retorna o modo da primeira coluna = 10.

#### Informação técnica

Esta função está disponível desde o LibreOffice 4.4.

Esta função não faz parte do padrão Open Document Format for Office Applications (OpenDocument) Versão 1.3. Parte 4: Formato de Fórmula Recalculada (OpenFormula). O espaço de nomes é

COM.MICROSOFT.AGGREGATE

Tópicos relacionados

Página wiki da função AGGREGAR.

MÉDIA, CONT.NÚM, CONT.VALORES, MAXIMO, MINIMO, MULT, DESVPAD.S, DESVPAD.P, SOMA, VAR.S, VAR.P, MED, MODO.ÚNICO, MAIOR, MENOR, PERCENTIL.INC , QUARTIL.INC, PERCENTIL.EXC, QUARTIL.EXC

Localizar rótulos de colunas e linhas automaticamente

♥ Doe para nosso projeto! ♥