#  Sed script to adapt several test scripts in ./tests.

/^fail=0$/ a\
\
case \$abs_top_srcdir in\
  .* ) abs_top_srcdir=\$(echo "\$abs_top_srcdir" | sed "s%^%../%");;\
esac\
case \$abs_srcdir in\
  .* ) abs_srcdir=\$(echo "\$abs_srcdir" | sed "s%^%../%");;\
esac\

/require_en_utf8_locale_/d
/LC_ALL=en_US.UTF-8/ c\
LC_ALL=C

/^grep_test.*x3.*y3.*-E -w --color=always bc$/ s/^/#/

/^# Lower and upper bound of valid exit status/, /^$/ {
  /^$/ a\
l=1 u=1 L=0 U=1
  s/^/# /
}

/printf .* >in/ a\
dtou in

/^foo=/,/^fail=0$/ {
  /^$/ i\
bar=$(test "X$DJGPP" != X) && skip_ "DJGPP does not support pcre jit"
}
